100 REM* BINARY TO GEOS V1.0 FROM AHOY!!
110 REM* (E)NGENDERED BY  SHAWN K. SMITH
120 PN$="PS TO GEOS":DATA 000,006,087,003,008,004,030
130 FORD=1TO16:P$=P$+CHR$(160):NEXT
140 PN$=MID$(PN$+P$,1,16):Z$=CHR$(0)
150 FORD=1TO7:READ DI(D):NEXT
160 PRINTCHR$(147):PRINT:PRINT
170 INPUT"ENTER NAME OF BINARY FILE";B$
180 OPEN1,8,15,"I0":OPEN8,8,8,B$+",P,R"
190 GOSUB220:GOSUB250:GOSUB390
200 PRINT:PRINTCHR$(18)PN$" CONVERTED!"
210 CLOSE8:CLOSE1:END
220 INPUT#1,E,E$,A$,A$:IFE=0THENRETURN
230 PRINT:PRINT"***";E;E$;" ***"
240 CLOSE8:CLOSE1:END
250 PRINT:PRINT"WORKING . . .":PRINT
260 T=18:S=1:CLOSE8:OPEN8,8,8,+"#"
270 PRINT#1,"U1"8;0;T;S:GOSUB220
280 PRINT#1,"B-P"8;0:GET#8,NT$,NS$
290 FORTB=2TO228STEP32:DN$=""
300 PRINT#1,"B-P"8;TB:GET#8,FT$,TD$,SD$
310 IFASC(FT$+Z$)<>130THEN350
320 FORD=1TO16:GET#8,N$:DN$=DN$+N$:NEXT
330 PRINTDN$,
340 IF DN$=MID$(B$+P$,1,16)THEN RETURN
350 NEXT:T=ASC(NT$+Z$):S=ASC(NS$+Z$)
360 IF T THEN270
370 PRINT"??? FILE NOT FOUND!"
380 CLOSE8:CLOSE1:END
390 PRINT#1,"U1"8;0;ASC(TD$)ASC(SD$)
400 PRINT#1,"B-P"8;0:GET#8,T2$,S2$
410 PRINT#1,"B-P"8;0:PRINT#8,CHR$(0)CHR$(255)CHR$(3)CHR$(21);
420 PRINT#1,"U2"8;0;ASC(TD$)ASC(SD$)
430 PRINT#1,"U1"8;0;T;S:PRINT#1,"B-P"8;TB:PRINT#8,CHR$(131);T2$S2$PN$TD$SD$;
440 FORD=1TO7:PRINT#8,CHR$(DI(D));:NEXT
450 PRINT#1,"U2"8;0;T;S
460 RETURN